• Պլանի վերանայում = ամեն ինչ վերակառուցել։ Ամեն փոփոխություն նշանակում էր թիրախները ձեռքով վերաբաշխել ըստ բաժինների և բրենդերի՝ ժամանակի հսկայական ծախս։
• Ռելյացիոն կապեր չկան՝ rollup չկա։ Պլանի և փաստի աղյուսակները կապված չէին։ «Պլան vs փաստ ըստ բրենդի՝ ալիքում»-ը հավաքվում էր ձեռքով՝ շաբաթական։
• Վիզուալիզացիան թույլ էր։ Առանց տվյալների մոդելի ցանկացած ամփոփում մեկ հարցի ստատիկ թերթ է։ Նոր կտրվածքը նշանակում էր նորից փորփրել արտահանումները։
• Պատասխանատու վերանշանակելը՝ աղետ։ Պատմությունը մի քանի աղյուսակում վերագրել առանց ինչ-որ բան կոտրելու՝ սխալների և կորած ժամանակի աղբյուր։
• Պլանավորման տարբեր խորություն։ Որոշ բրենդեր պլանավորվում էին մանրամասն՝ ըստ ապրանքի, մյուսները՝ ընդհանուր գծերով ըստ բրենդի և ալիքի։ Երկու մոտեցումը մեկ՝ փաստի հետ համեմատելի պատկերի ձեռքով համադրելը գրեթե անհնար է։

Ճարտարապետություն

Սկզբունքը նույնն է, ինչ հաճախորդի մյուս մոդուլներում՝ QuickBooks-ից քաշել միայն չմշակված տվյալ պարզ արտահանմամբ, և ամբողջ տրամաբանությունը՝ նորմալացում, պլանի բաշխում, պլան/փաստ հաշվարկ՝ պահել Excel-մոդելում։ Պլանը, մինչդեռ, դրվում է ոչ QuickBooks-ում և ոչ կոդում, այլ Google Sheets-ում։

QuickBooks-ը այստեղ ոչ ինտեգրացիա է, ոչ կարգաբերում. մենեջերը վաճառքն արտահանում է ստանդարտ «ֆայլ» կոճակով։ Այդ արտահանումների ամբողջ «կեղտը» (աղբ-տողեր, ռեգիստր, անվանումների անհամապատասխանություն, ընդամենը-տողեր) մաքրվում է M-կոդի ներսում։ Պլանն ընդհանրապես չի անցնում QuickBooks-ով՝ այն ապրում է Google Sheets-ում և քաշվում ուղիղ այնտեղից։

Պլանի մուտքագրման երկու ռեժիմ — մեկ ելքային աղյուսակ

Ղեկավարությունը պլանավորում է տարբեր կերպ՝ կախված բրենդից, և այդ սովորությունը կոտրելը սխալ կլիներ։ Այնպես որ Google Sheets-ն ունի երկու թերթ, և մոդելն ինքն է դրանք բերում ընդհանուր տեսքի։

Վերջնական Plans հարցումը երկու նորմալացված ճյուղի միաձուլում է՝ նույնական սյունակներով աղյուսակի՝ Բրենդ, Ալիք, Ներկ., Ամսաթիվ, Եռամսյակ, SKU, Պլան (֏), Պլան (հատ)։

-- «Plans» հարցում (վերջնական)՝ երկու պլանավորման ռեժիմի միություն
let
    Source = Table.Combine({
        #"Plans without item detail",   -- ամփոփ՝ բրենդ × ալիք × ներկ.
        #"Plans with item detail"       -- մանրամասն՝ ըստ SKU
    }),
    Types = Table.TransformColumnTypes(Source, {
        {"Sales plan ($)",    type number},
        {"Sales plan (units)", type number}
    })
in
    Types

Google Sheets-ի բազմատող վերնագրի վերլուծություն

Պլանի աղյուսակում ղեկավարությունը տվյալները պահում է «լայն» ձևով, որ հաճելի է աչքին՝ բրենդ/SKU ձախում, իսկ վերնագիրը մի քանի տող է (ամիս, ալիք, ներկ., պլանի տեսակ $/հատ)։ Մոդելին պետք է նորմալ (երկար) ձև։ Հնարքը՝ վերնագրի տողերը սոսնձել մեկ բաղադրյալ վերնագրի՝ @ բաժանարարով, շրջել աղյուսակը, հետո վերնագիրը հետ տրոհել։

-- Բաղադրյալ վերնագիր կառուցել մի քանի վերնագիր-տողերից
Headers = Table.SelectRows(
    Table.Transpose( Table.FirstN(Cleaned, 4) ),   -- 4 վերնագիր-տող
    each not List.IsEmpty(List.RemoveMatchingItems(Record.FieldValues(_), {"", null}))
),
Combined = Table.CombineColumns(
    Table.FillDown(Headers, Table.ColumnNames(Headers)),
    Table.ColumnNames(Headers),
    each Text.Combine(_, "@"), "Combined"
)[Combined],

-- «Լայն»-ից «երկար» շրջել և վերնագիրը հետ տրոհել
Long   = Table.UnpivotOtherColumns(Tbl,
    {"Brand", "Item.SKU", "Item"}, "Attribute", "Value"),
Parsed = Table.SplitColumn(Long, "Attribute",
    Splitter.SplitTextByDelimiter("@", QuoteStyle.Csv),
    {"Plan month", "Sales channel", "Rep", "Plan type"})

Բաշխում #1՝ ամիս → օր

Ղեկավարությունը պլանը դնում է ըստ ամսի, բայց փաստերը գալիս են ըստ օրվա։ Դրանք ցանկացած կտրվածքով համեմատելի դարձնելու համար (օր, շաբաթ, ամիս, եռամսյակ) ամսական պլանը «բաշխվում» է օրերին՝ հարցումը միացնում է Calendar-ը ամսվա առաջին օրով և արժեքը բաժանում օրերի քանակի։

-- Միացնել Calendar; օրական պլան = ամսական ÷ ամսվա օրեր
WithCalendar = Table.NestedJoin(Parsed, {"Plan month"},
    Calendar, {"FirstDayOfMonth"}, "Cal", JoinKind.LeftOuter),
Expanded     = Table.ExpandTableColumn(WithCalendar, "Cal",
    {"Date", "Quarter", "DaysInMonth"}),
Daily        = Table.AddColumn(Expanded, "Daily Plan",
    each [Value] / [DaysInMonth])

Այս քայլը կոմպակտ GS-պլանը վերածում է օրական աղյուսակի՝ մի քանի բրենդով, ալիքով և ներկայացուցչով մեկ տարին գումարվում է մեկ միլիոնից ավելի տող։ Բայց այնուհետև ցանկացած ժամանակահատված պարզ գումար է՝ առանց «բայց փետրվարը 28 օր է» վերապահման։

Բաշխում #2՝ բրենդ → SKU (ըստ վաճառքի մասնաբաժնի)

Ամփոփ թերթում պլանը դրվում է ըստ բրենդի և ալիքի՝ առանց ապրանքային տրոհման։ Այն SKU-ով փաստերի հետ համեմատելու համար մենք պլանը բաշխում ենք ամեն SKU-ի՝ բրենդի վաճառքի մասնաբաժնի համամասնությամբ վերջին 5 ամսում՝ պլանը «ինքնակարգավորվում» է ընթացիկ ապրանքային խառնուրդին։ Սկզբում առանձին հարցում հաշվում է կշիռները։

-- SKU-ի կշիռը բրենդի ներսում (վաճառք վերջին 5 ամսում)
ByBrand = Table.Buffer( Table.Group(Recent, {"Brand"},
    {{"Brand $", each List.Sum([#"Sales ($)"]), type number}}) ),
BySKU   = Table.Group(Recent, {"Item.SKU", "Brand"},
    {{"$", each List.Sum([#"Sales ($)"]), type number}}),
WithShare = Table.AddColumn(Expanded2, "$ share", each [#"$"] / [#"Brand $"], type number)

Հետո ամփոփ պլանը բազմապատկվում է այս կշիռներով՝ բրենդի թիրախը տրոհվում է կոնկրետ SKU-ների, և միջին գնի միջոցով նաև փոխարկվում հատերի։

-- Բրենդի պլան → SKU-պլան՝ վաճառքի մասնաբաժնի համամասնությամբ
PlanUSD = Table.AddColumn(Expanded3, "Sales plan ($)",
    each [Daily Plan] * [#"$ share"], type number),
PlanUnits = Table.AddColumn(PlanUSD, "Sales plan (units)",
    each [#"Sales plan ($)"] / [Unit price], type number)

Ռելյացիոն մոդել՝ աստղ՝ ձեռքով rollup-ի փոխարեն

Նախկինում պակասող գլխավորը կապերն էին։ Հիմա Plans աղյուսակը փաստ-աղյուսակն է աստղի կենտրոնում՝ շրջապատված փնտրումներով, որոնք ֆիլտրում են այն ինքնաշխատ։

Կապերը տալիս են վարժության ողջ իմաստը՝ ֆիլտրը ցանկացած փնտրման վրա ինքնաշխատ հասնում է թե՛ պլանին, թե՛ փաստին։ Ընտրեք ղեկավար՝ պլանն ու փաստը վերահաշվում են նրա բոլոր ներկայացուցիչներով, ընտրեք եռամսյակ՝ երկու աղյուսակն էլ ֆիլտրվում են։ Ներկ. → Ղեկավար կապը տալիս է rollup ըստ հիերարխիայի՝ առանց ձեռքով ամփոփման։

Բաշխում #3՝ ներկայացուցչի պլան → հաճախորդ (դինամիկ, DAX-ում)

Երրորդ բաշխումն աշխատում է ոչ թե թարմացման, այլ հարցման պահին։ Պլանը դրվում է ներկ., բրենդ և ալիք վրա՝ աղյուսակում հաճախորդ չկա։ Բայց մենեջերին պետք է կտրվածք ըստ հաճախորդի։ Տվյալներն այդպիսի պատասխան չունեն՝ չափիչը կառուցում է այն՝ բաշխելով պլանը ամեն հաճախորդի փաստացի վաճառքի մասնաբաժնի համամասնությամբ։

-- [Plan $] — բաշխել պլանը ընթացիկ կտրվածքին՝ ըստ փաստի մասնաբաժնի
IF( [Sold $],
    SUM('Plans'[Sales plan ($)]) *
    DIVIDE(
        [Sold $],
        CALCULATE([Sold $], ALL('Dim_Clients'[Client])),
        0
    )
)

Չափիչը վերցնում է պլանը ընթացիկ համատեքստում և բազմապատկում հաճախորդի վաճառքի մասնաբաժնով։ Մեկ հաճախորդի համար DIVIDE-ը վերադարձնում է նրա մասնաբաժինը, առանց հաճախորդ-ֆիլտրի մասնաբաժինը հավասար է մեկի՝ և չափիչը վերադարձնում է ողջ պլանը։ Նույն հնարքը պլանը բաշխում է ցանկացած կտրվածքի՝ առանց ուղիղ պլանի։

Պլան ցանկացած ժամանակահատվածի և % կատարման

Պլանը բերված է օրական մանրությանն ու կապված է Օրացույցին, այնպես որ ցանկացած ժամանակահատված ֆիլտրի հարց է։ Եռամսյակային չափիչները սովորական CALCULATE են՝ ամսվա սահմաններով, իսկ պլանի կատարումը՝ փաստի հարաբերությունը պլանին՝ ճիշտ ցանկացած մանրության մակարդակում։

-- [Plan $ 2026 Q2]
CALCULATE( SUM('Plans'[Sales plan ($)]),
    FILTER( ALL('Calendar'),
        YEAR('Calendar'[Date]) = 2026 &&
        MONTH('Calendar'[Date]) >= 4 && MONTH('Calendar'[Date]) <= 6 ))

-- [% of plan $] և [% of plan units]
DIVIDE( [Sold $],    [Plan $] )
DIVIDE( [Sold units], [Plan units] )